OUTPUT_FORMAT("elf32-h8300")
OUTPUT_ARCH(h8300h)
ENTRY("_start")
MEMORY
{
	vectors(r)	: o = 0x000000, l = 0x000100
	rom(rx)		  : o = 0x000100, l = 0x07FF00
	ram(rwx)	  : o = 0xFFBF20, l = 0x004000
	stack(rw)	  : o = 0xFFFF0C, l = 0x000004
}

SECTIONS
{
.vectors : {
  /* 割り込みベクタテーブル */
	LONG(ABSOLUTE(_start))		/*  0 Reset vector */
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(DEFINED(_int_nmi)?ABSOLUTE(_int_nmi):ABSOLUTE(_start))
	LONG(DEFINED(_int_trap0)?ABSOLUTE(_int_trap0):ABSOLUTE(_start))
	LONG(DEFINED(_int_trap1)?ABSOLUTE(_int_trap1):ABSOLUTE(_start))
	LONG(DEFINED(_int_trap2)?ABSOLUTE(_int_trap2):ABSOLUTE(_start))
	LONG(DEFINED(_int_trap3)?ABSOLUTE(_int_trap3):ABSOLUTE(_start))
	LONG(DEFINED(_int_irq0)?ABSOLUTE(_int_irq0):ABSOLUTE(_start))
	LONG(DEFINED(_int_irq1)?ABSOLUTE(_int_irq1):ABSOLUTE(_start))
	LONG(DEFINED(_int_irq2)?ABSOLUTE(_int_irq2):ABSOLUTE(_start))
	LONG(DEFINED(_int_irq3)?ABSOLUTE(_int_irq3):ABSOLUTE(_start))
	LONG(DEFINED(_int_irq4)?ABSOLUTE(_int_irq4):ABSOLUTE(_start))
	LONG(DEFINED(_int_irq5)?ABSOLUTE(_int_irq5):ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))

	LONG(DEFINED(_int_wovi)?ABSOLUTE(_int_wovi):ABSOLUTE(_start))
	LONG(DEFINED(_int_cmi)?ABSOLUTE(_int_cmi):ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(DEFINED(_int_adi)?ABSOLUTE(_int_adi):ABSOLUTE(_start))
	LONG(DEFINED(_int_imia0)?ABSOLUTE(_int_imia0):ABSOLUTE(_start))
	LONG(DEFINED(_int_imib0)?ABSOLUTE(_int_imib0):ABSOLUTE(_start))
	LONG(DEFINED(_int_ovi0)?ABSOLUTE(_int_ovi0):ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(DEFINED(_int_imia1)?ABSOLUTE(_int_imia1):ABSOLUTE(_start))
	LONG(DEFINED(_int_imib1)?ABSOLUTE(_int_imib1):ABSOLUTE(_start))
	LONG(DEFINED(_int_ovi1)?ABSOLUTE(_int_ovi1):ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(DEFINED(_int_imia2)?ABSOLUTE(_int_imia2):ABSOLUTE(_start))
	LONG(DEFINED(_int_imib2)?ABSOLUTE(_int_imib2):ABSOLUTE(_start))
	LONG(DEFINED(_int_ovi2)?ABSOLUTE(_int_ovi2):ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(DEFINED(_int_cmia0)?ABSOLUTE(_int_cmia0):ABSOLUTE(_start))
	LONG(DEFINED(_int_cmib0)?ABSOLUTE(_int_cmib0):ABSOLUTE(_start))
	LONG(DEFINED(_int_cmiab1)?ABSOLUTE(_int_cmiab1):ABSOLUTE(_start))
	LONG(DEFINED(_int_tovi01)?ABSOLUTE(_int_tovi01):ABSOLUTE(_start))
	LONG(DEFINED(_int_cmia2)?ABSOLUTE(_int_cmia2):ABSOLUTE(_start))
	LONG(DEFINED(_int_cmib2)?ABSOLUTE(_int_cmib2):ABSOLUTE(_start))
	LONG(DEFINED(_int_cmiab3)?ABSOLUTE(_int_cmiab3):ABSOLUTE(_start))
	LONG(DEFINED(_int_tovi23)?ABSOLUTE(_int_tovi23):ABSOLUTE(_start))
	LONG(DEFINED(_int_dend0a)?ABSOLUTE(_int_dend0a):ABSOLUTE(_start))
	LONG(DEFINED(_int_dend0b)?ABSOLUTE(_int_dend0b):ABSOLUTE(_start))
	LONG(DEFINED(_int_dend1a)?ABSOLUTE(_int_dend1a):ABSOLUTE(_start))
	LONG(DEFINED(_int_dend1b)?ABSOLUTE(_int_dend1b):ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(ABSOLUTE(_start))
	LONG(DEFINED(_int_eri0)?ABSOLUTE(_int_eri0):ABSOLUTE(_start))
	LONG(DEFINED(_int_rxi0)?ABSOLUTE(_int_rxi0):ABSOLUTE(_start))
	LONG(DEFINED(_int_txi0)?ABSOLUTE(_int_txi0):ABSOLUTE(_start))
	LONG(DEFINED(_int_tei0)?ABSOLUTE(_int_tei0):ABSOLUTE(_start))
	LONG(DEFINED(_int_eri1)?ABSOLUTE(_int_eri1):ABSOLUTE(_start))
	LONG(DEFINED(_int_rxi1)?ABSOLUTE(_int_rxi1):ABSOLUTE(_start))
	LONG(DEFINED(_int_txi1)?ABSOLUTE(_int_txi1):ABSOLUTE(_start))
	LONG(DEFINED(_int_tei1)?ABSOLUTE(_int_tei1):ABSOLUTE(_start))
	LONG(DEFINED(_int_eri2)?ABSOLUTE(_int_eri2):ABSOLUTE(_start))
	LONG(DEFINED(_int_rxi2)?ABSOLUTE(_int_rxi2):ABSOLUTE(_start))
	LONG(DEFINED(_int_txi2)?ABSOLUTE(_int_txi2):ABSOLUTE(_start))
	LONG(DEFINED(_int_tei2)?ABSOLUTE(_int_tei2):ABSOLUTE(_start))
	FILL(0xff)
	}  > vectors

.text :	{
	*(.text)
  *(.rodata*)
  *(.strings)
   	 _etext = . ;
	}  > rom


.tors : {
	___ctors = . ;
	*(.ctors)
	___ctors_end = . ;
	___dtors = . ;
	*(.dtors)
	___dtors_end = . ;
	}  > rom

.data : AT (ADDR(.tors)+SIZEOF(.tors))
{
	_data = . ;
	*(.data)
	_edata = . ;
} > ram


.bss : {
	 _bss_start = . ;
	*(.bss)
	*(COMMON)
	 _end = . ;
	}  > ram

.stack : {
	 _stack = . ;
	*(.stack)
	}  > stack

.stab 0 (NOLOAD) : {
	[ .stab ]
	}
.stabstr 0 (NOLOAD) : {
	[ .stabstr ]
	}
}